1 files changed, 55 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..c7ec6febfa88
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,55 @@
+# Maintainer: sp1rit <sp1rit@pm.me>
+
+_pkgname=cadmus
+
+pkgname="${_pkgname}"-appimage
+pkgver=0.0.1
+pkgrel=1
+pkgdesc="A GUI frontend for @werman's Pulse Audio real-time noise suppression plugin "
+arch=("x86_64")
+url="https://github.com/josh-richardson/cadmus/"
+license=("GPL-3.0")
+depends=("zlib")
+options=(!strip)
+_appimage="${pkgname}-${pkgver}.AppImage"
+source_x86_64=("${_appimage}::https://github.com/josh-richardson/cadmus/releases/download/${pkgver}/${_pkgname}.AppImage"
+               "https://raw.githubusercontent.com/josh-richardson/cadmus/${pkgver}/LICENSE"
+              )
+noextract=("${_appimage}")
+sha256sums_x86_64=('1008ec442062439e93d3d06178135b84a1260ee9f4c7fe0657d991a6386c187f'
+                   '3972dc9744f6499f0f9b2dbf76696f2ae7ad8af9b23dde66d6af86c9dfb36986')
+
+prepare() {
+    chmod +x "${_appimage}"
+    ./"${_appimage}" --appimage-extract
+}
+
+build() {
+    # Adjust .desktop so it will work outside of AppImage container
+    sed -i -E "s|Exec=AppRun|Exec=env DESKTOPINTEGRATION=false /usr/bin/${_pkgname}|"\
+        "squashfs-root/${_pkgname}.desktop"
+    # Fix permissions; .AppImage permissions are 700 for all directories
+    chmod -R a-x+rX squashfs-root/usr
+}
+
+package() {
+    # AppImage
+    install -Dm755 "${srcdir}/${_appimage}" "${pkgdir}/opt/${pkgname}/${pkgname}.AppImage"
+    install -Dm644 "${srcdir}/LICENSE" "${pkgdir}/opt/${pkgname}/LICENSE"
+
+    # Desktop file
+    install -Dm644 "${srcdir}/squashfs-root/${_pkgname}.desktop"\
+            "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
+
+    # Icon images
+    install -dm755 "${pkgdir}/usr/share/"
+    cp -a "${srcdir}/squashfs-root/usr/share/icons" "${pkgdir}/usr/share/"
+
+    # Symlink executable
+    install -dm755 "${pkgdir}/usr/bin"
+    ln -s "/opt/${pkgname}/${pkgname}.AppImage" "${pkgdir}/usr/bin/${_pkgname}"
+
+    # Symlink license
+    install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}/"
+    ln -s "/opt/$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
+}