1 files changed, 41 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..ee0c4a3fe11e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Martin Thierer <thierer@web.de>
+
+pkgname=cc1541-git
+pkgver=3.2.r25.gb613ed8
+pkgrel=1
+pkgdesc='Tool for creating .d64 images with custom sector interleaving etc.'
+url='https://bitbucket.org/PTV_Claus/cc1541/src/master/'
+license=('custom')
+makedepends=('git' 'asciidoc')
+provides=('cc1541')
+arch=('x86_64')
+source=("${pkgname}::git+https://bitbucket.org/PTV_Claus/cc1541.git")
+md5sums=('SKIP')
+
+pkgver() {
+  cd "${srcdir}/${pkgname}"
+
+  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "${srcdir}/${pkgname}"
+
+  make cc1541 man
+}
+
+check() {
+  cd "${srcdir}/${pkgname}"
+
+  make check
+  ./test_cc1541 ./cc1541
+}
+
+package() {
+  cd "${srcdir}/${pkgname}"
+
+  install -D -m755 -t ${pkgdir}/usr/bin/ cc1541
+  install -D -m644 -t ${pkgdir}/usr/share/doc/${pkgname}/ README.md
+  install -D -m644 -t ${pkgdir}/usr/share/licenses/${pkgname}/ LICENSE.txt
+  install -D -m644 -t ${pkgdir}/usr/share/man/man1/ cc1541.1
+}