1 files changed, 71 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..bd6dc2ed025b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,71 @@
+# Maintainer: Core_UK <mail.coreuk@gmail.com>
+
+pkgname=cider
+_pkgname=Cider
+pkgver=1.0.0.198.2087be2
+pkgrel=1
+pkgdesc="Project Cider. A new look into listening and enjoying music in style and performance. This is a git package, thus it compiles straight from the GitHub repository."
+arch=("armv7h" "i686" "x86_64")
+url="https://github.com/CiderApp/${_pkgname}.git"
+license=("MIT")
+depends=('gtk3' 'libxss' 'nss')
+makedepends=('yarn' 'git' 'npm' 'nodejs-lts-gallium')
+optdepends=('libnotify: Playback notifications'
+            'otf-san-francisco: Use of SF Font for certain themes')
+source=(
+  "git+https://github.com/CiderApp/${_pkgname}.git"
+  "Cider.desktop"
+)
+sha256sums=('SKIP'
+            '30d7e8a6d4c90dc5a2f9e009728f9d8ae4de08c6ad7b25c6e7f5509b1bab6fe0')
+
+pkgver() {
+	cd "$srcdir/$_pkgname"
+    var=$(grep '"version":.*' package.json | cut -d '"' -f 4 | head -1)
+    echo ${var/-/.}.$(git rev-list --count HEAD).$(git rev-parse --short HEAD)
+}
+
+build() {
+    cd "${srcdir}/${_pkgname}"
+    echo "Building ${_pkgname} on v${pkgver} : [Install Build Dependencies] | Build | Done"
+    yarn install --non-interactive --pure-lockfile --cache-folder "${srcdir}/yarn-cache"
+
+    echo "Building : Install Build Dependencies | [Build] | Done"
+    if [[ ${CARCH} == "armv7h" ]]; then
+        yarn electron-builder build --armv7l --linux dir
+    elif [[ ${CARCH} == "i686" ]]; then
+        yarn electron-builder build --ia32 --linux dir
+    elif [[ ${CARCH} == "x86_64" ]]; then
+        yarn electron-builder build --x64 --linux dir
+    fi
+
+    echo "Building : Install Build Dependencies | Build | [Done]"
+}
+ 
+package() {
+    cd "${srcdir}/${_pkgname}"
+
+    echo "Packaging : [Desktop Shortcut] | Icon | Build Files | Other Files | Done"
+    install -Dm644 "${srcdir}/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
+    echo "Packaging : Desktop Shortcut | [Icon] | Build Files | Other Files | Done"
+    install -Dm644 "${srcdir}/${_pkgname}/resources/icons/icon.png" "${pkgdir}/usr/share/icons/hicolor/256x256/apps/${pkgname%-git}.png"
+
+
+    echo "Packaging : Desktop Shortcut | Icon | [Build Files] | Other Files | Done"
+    install -d "$pkgdir/opt/"
+    install -d "$pkgdir/usr/bin/"
+    cd ${srcdir}/${_pkgname}/dist/linux-unpacked
+    mkdir "${pkgdir}/opt/${pkgname%-git}"
+    cp -r --preserve=mode * "${pkgdir}/opt/${pkgname%-git}"
+    ln -sf "/opt/${pkgname%-git}/${pkgname%-git}" "${pkgdir}/usr/bin/${pkgname%-git}"
+
+
+    echo "Packaging : Desktop Shortcut | Icon | Build Files | [Other Files] | Done"
+    install -d "$pkgdir/usr/share/licenses" "$pkgdir/usr/share/doc"
+    install -Dm644 "${srcdir}/${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    install -Dm644 "${srcdir}/${_pkgname}/README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
+
+
+    echo "Packaging : Desktop Shortcut | Icon | Build Files | Other Files | [Done]"
+}
+