summarylogtreecommitdiffstats
path: root/PKGBUILD
diff options
context:
space:
mode:
Diffstat (limited to 'PKGBUILD')
-rw-r--r--PKGBUILD47
1 files changed, 47 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..1b60730e2063
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Jonas Witschel <diabonas at gmx dot de>
+pkgname=clevis-git
+pkgver=11.r0.3375b08
+pkgrel=1
+pkgdesc='Automated Encryption Framework'
+arch=('x86_64')
+url='https://github.com/latchset/clevis'
+license=('GPL3')
+depends=('jose' 'bash')
+makedepends=('git' 'meson'
+ # Optional components, must be present during build to enable corresponding features
+ 'asciidoc' # man page support
+ 'bash-completion' # Bash completion support
+ 'luksmeta' 'libpwquality' # LUKS unlocker support'
+ 'tpm2-tools' # TPM pin support
+ 'udisks2') # UDisks2 unlocker support
+checkdepends=('tang')
+optdepends=('luksmeta: LUKS and UDisks2 unlocker support'
+ 'libpwquality: LUKS unlocker support'
+ 'curl: Tang pin support'
+ 'tpm2-tools: TPM2 pin support'
+ 'udisks2: UDisks2 unlocker support')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("git+$url.git")
+sha512sums=('SKIP')
+
+pkgver() {
+ cd "${pkgname%-git}"
+ printf '%s' "$(git describe --long --tags | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g')"
+}
+
+build() {
+ cd "${pkgname%-git}"
+ arch-meson build
+ ninja -C build
+}
+
+check() {
+ cd "${pkgname%-git}"
+ ninja -C build test
+}
+
+package() {
+ cd "${pkgname%-git}"
+ DESTDIR="$pkgdir/" ninja -C build install
+}