1 files changed, 50 insertions, 13 deletions
diff --git a/PKGBUILD b/PKGBUILD
index 002d06ce6312..ee9903103fee 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,21 +1,58 @@
+# Maintainer: Carl Smedstad <carsme@archlinux.org>
+# Contributor: Richard Quirk
+
 pkgname=cmake-lint
-pkgver=1.3.4.1
-pkgrel=1
+pkgver=1.4.2
+pkgrel=6
 pkgdesc="Check for coding style issues in CMake files"
-arch=('any')
-url="http://github.com/richq/cmake-lint/"
-license=('APACHE')
-depends=('python')
-makedepends=('python-setuptools')
-source=("https://github.com/richq/$pkgname/archive/v$pkgver.tar.gz")
-md5sums=('960df861a984e721df08e2c57eb18e36')
+arch=(any)
+url="https://github.com/cmake-lint/cmake-lint"
+license=(Apache-2.0)
+depends=(python)
+makedepends=(
+  python-build
+  python-installer
+  python-pytest-runner
+  python-setuptools
+  python-wheel
+)
+checkdepends=(python-pytest)
+source=(
+  "$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz"
+  "python3.12-compatibility.patch"
+)
+sha256sums=(
+  'bf060987c74e07890f7314a4832c2e54ffb9c5c1e6d799387bc438010f918676'
+  '4f1573fa02d542067f0d20eb178f50354bed451173c4f73175098ca4c6e569c1'
+)
+
+_archive="$pkgname-$pkgver"
+
+prepare() {
+  cd "$_archive"
+
+  patch --forward --strip=1 --input="$srcdir/python3.12-compatibility.patch"
+}
 
 build() {
-  cd "$srcdir/$pkgname-$pkgver"
-  python setup.py build
+  cd "$_archive"
+
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd "$_archive"
+
+  rm -rf tmp_install
+  python -m installer --destdir=tmp_install dist/*.whl
+
+  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
+  export PYTHONPATH="$PWD/tmp_install/$site_packages"
+  pytest --override-ini="addopts="
 }
 
 package() {
-  cd "$srcdir/$pkgname-$pkgver"
-  python ./setup.py install --prefix=/usr --root="$pkgdir"
+  cd "$_archive"
+
+  python -m installer --destdir="$pkgdir" dist/*.whl
 }