1 files changed, 57 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..349a135539bc
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,57 @@
+# Maintainer: Eric Engestrom <aur [at] engestrom [dot] ch>
+
+pkgname=cmtp-responder-git
+pkgver=r240.3218119b9b
+pkgrel=1
+pkgdesc="Media Transfer Protocol daemon (responder) written in C, with minimal dependencies"
+arch=('x86_64')
+url="https://github.com/cmtp-responder/cmtp-responder"
+license=('Apache')
+source=("git+$url")
+sha256sums=('SKIP')
+depends=('glib2' 'systemd-libs')
+makedepends=('cmake')
+conflicts=('cmtp-responder')
+provides=("cmtp-responder")
+
+pkgver() {
+  cd cmtp-responder
+  printf 'r%d.%s' \
+    $(git rev-list --count HEAD) \
+    $(git rev-parse --short=10 HEAD)
+}
+
+prepare() {
+  sed 's/-Werror-implicit-function-declaration/-Werror=implicit-function-declaration/' -i cmtp-responder/CMakeLists.txt
+  sed '/cmtp-responder.conf/d' -i cmtp-responder/CMakeLists.txt
+
+  if [ -d build ]
+  then
+    msg2 "Build dir already exist; doing an incremental build"
+    msg2 "If you want to do a clean build, please delete $(realpath build)"
+    return
+  fi
+
+  cmake \
+    -DCMAKE_BUILD_DESCRIPTORS=true \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -S cmtp-responder -B build
+}
+
+build() {
+  make -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" make -C build install
+
+  install -dm755 "$pkgdir"/usr/lib/udev/rules.d/
+  install -m644 cmtp-responder/packaging/99-mtp-responder.rules "$pkgdir"/usr/lib/udev/rules.d/
+
+  install -dm755 "$pkgdir"/usr/lib/systemd/system/
+  install -m644 \
+    cmtp-responder/mtp-responder.service \
+    cmtp-responder/mtp-responder.socket \
+    "$pkgdir"/usr/lib/systemd/system/
+}