1 files changed, 70 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..3b1f662d67fc
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,70 @@
+# Maintainer: archlinux.info:tdy
+
+pkgbase=cutechess
+pkgname=(cutechess cutechess-cli libcutechess libcutechess-docs)
+pkgver=0.9.4
+pkgrel=1
+pkgdesc="Tools for working with chess engines"
+arch=(i686 x86_64)
+url=http://cutechess.com
+license=(GPL3)
+depends=(qt5-svg)
+makedepends=(doxygen)
+source=(https://github.com/$pkgname/$pkgname/archive/gui-$pkgver.tar.gz)
+sha256sums=(315676ce661729e9acabb741ab538196ae85019efab4e3f9e4a08c3410580af8)
+
+prepare() {
+  cd $pkgbase-gui-$pkgver/projects
+  sed -n '2,23s:^[ ]*::p' gui/components/pgnhighlighter/src/pgnhighlighter.h > COPYING.gui
+  sed -n '2,23s:^[ ]*::p' lib/components/json/src/jsonparser.h > COPYING.lib
+}
+
+build() {
+  cd $pkgbase-gui-$pkgver
+  qmake
+  make
+}
+
+package_cutechess() {
+  pkgdesc="A graphical interface for chess"
+  license=(GPL3 MIT)
+
+  cd $pkgbase-gui-$pkgver/projects
+  install -Dm755 gui/$pkgname "$pkgdir"/usr/bin/$pkgname
+  install -Dm644 COPYING.gui "$pkgdir"/usr/share/licenses/$pkgname/COPYING
+}
+
+package_cutechess-cli() {
+  pkgdesc="A command-line tool to automate chess engine tournaments"
+  depends=(qt5-base)
+
+  cd $pkgbase-gui-$pkgver
+  install -Dm755 projects/cli/$pkgname "$pkgdir"/usr/bin/$pkgname
+  install -Dm644 docs/$pkgname.6 "$pkgdir"/usr/share/man/man6/$pkgname.6
+  install -Dm644 docs/engines.json.5 "$pkgdir"/usr/share/man/man5/engines.json.5
+}
+
+package_libcutechess() {
+  pkgdesc="A static library for chess"
+  license=(GPL3 MIT)
+  depends=()
+  options=(staticlibs)
+
+  cd $pkgbase-gui-$pkgver/projects
+  install -Dm644 lib/$pkgname.a "$pkgdir"/usr/lib/$pkgname.a
+  install -Dm644 COPYING.lib "$pkgdir"/usr/share/licenses/$pkgname/COPYING
+}
+
+package_libcutechess-docs() {
+  pkgdesc="API documentation for libcutechess"
+  arch=(any)
+  depends=()
+  options=(docs)
+
+  cd $pkgbase-gui-$pkgver
+  make doc-api
+  install -dm755 "$pkgdir"/usr/share/doc/${pkgname%-*}/html/
+  install -m644 docs/api/html/* "$pkgdir"/usr/share/doc/${pkgname%-*}/html/
+  sed -i "s:$srcdir/$pkgbase-gui-$pkgver/docs/api:/usr/share/${pkgname%-*}/html:g" \
+    -s "$pkgdir"/usr/share/doc/${pkgname%-*}/html/*.html
+}