1 files changed, 51 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..71b0da7d6d39
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: CountStarlight <countstarlight@gmail.com>
+
+pkgname=deepin-wine-wechat
+pkgver=2.6.2
+deepinwechatver=2.6.2.31deepin0
+pkgrel=0
+pkgdesc="Tencent WeChat (com.wechat) on Deepin Wine For Archlinux"
+arch=("x86_64")
+url="https://weixin.qq.com/"
+license=('custom')
+depends=('p7zip' 'wine' 'wine-mono' 'wine_gecko' 'xorg-xwininfo' 'xdotool' 'wqy-microhei' 'adobe-source-han-sans-cn-fonts' 'lib32-alsa-lib' 'lib32-alsa-plugins' 'lib32-libpulse' 'lib32-openal' 'lib32-mpg123')
+conflicts=('deepin-wechat')
+install="deepin-wine-wechat.install"
+_mirror="https://mirrors.ustc.edu.cn/deepin"
+source=("$_mirror/pool/non-free/d/deepin.com.wechat/deepin.com.wechat_${deepinwechatver}_i386.deb"
+  "run.sh"
+  "reg_files.tar.bz2"
+  "update.policy")
+md5sums=('c66a173fe6817afd898e0061d9eaf42e'
+  '8a47e1c10ff08a9592fbb5a76dc69982'
+  'ebde755e3bd213550f5ccc69d3192060'
+  'a66646b473a3fbad243ac1afd64da07a')
+
+build() {
+  msg "Extracting DPKG package ..."
+  mkdir -p "${srcdir}/dpkgdir"
+  tar -xvf data.tar.xz -C "${srcdir}/dpkgdir"
+  sed "s/\(Categories.*$\)/\1Network;/" -i "${srcdir}/dpkgdir/usr/share/applications/deepin.com.wechat.desktop"
+  msg "Extracting Deepin Wine WeChat archive ..."
+  7z x -aoa "${srcdir}/dpkgdir/opt/deepinwine/apps/Deepin-WeChat/files.7z" -o"${srcdir}/deepinwechatdir"
+  msg "Adding config files and fonts"
+  tar -jxvf reg_files.tar.bz2 -C "${srcdir}/"
+  cp userdef.reg "${srcdir}/deepinwechatdir/userdef.reg"
+  cp system.reg "${srcdir}/deepinwechatdir/system.reg"
+  cp update.policy "${srcdir}/deepinwechatdir/update.policy"
+  cp user.reg "${srcdir}/deepinwechatdir/user.reg"
+  ln -sf "/usr/share/fonts/wenquanyi/wqy-microhei/wqy-microhei.ttc" "${srcdir}/deepinwechatdir/drive_c/windows/Fonts/wqy-microhei.ttc"
+  ln -sf "/usr/share/fonts/adobe-source-han-sans/SourceHanSansCN-Medium.otf" "${srcdir}/deepinwechatdir/drive_c/windows/Fonts/SourceHanSansCN-Medium.otf"
+  msg "Repackaging app archive ..."
+  7z a -t7z -r "${srcdir}/files.7z" "${srcdir}/deepinwechatdir/*"
+}
+
+package() {
+  msg "Preparing icons ..."
+  install -d "${pkgdir}/usr/share"
+  cp -a ${srcdir}/dpkgdir/usr/share/* "${pkgdir}/usr/share/"
+  msg "Copying WeChat to /opt/deepinwine/apps/Deepin-WeChat ..."
+  install -d "${pkgdir}/opt/deepinwine/apps/Deepin-WeChat"
+  install -m644 "${srcdir}/files.7z" "${pkgdir}/opt/deepinwine/apps/Deepin-WeChat/"
+  install -m755 "${srcdir}/run.sh" "${pkgdir}/opt/deepinwine/apps/Deepin-WeChat/"
+}