1 files changed, 40 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..ad76e613603d
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: vitaliikuzhdin <vitaliikuzhdin@gmail.com>
+
+pkgname="fast-ssh"
+pkgver=0.3.2
+pkgrel=1
+pkgdesc="Quickly connect to your services by navigating through your SSH config"
+arch=('any')
+url="https://github.com/Julien-R44/${pkgname}"
+license=('MIT')
+depends=('glibc' 'gcc-libs' 'openssh')
+makedepends=('cargo')
+_pkgsrc="${pkgname}-${pkgver}"
+source=("${_pkgsrc}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
+sha256sums=('36f9bbd91297766cd72d40a1db6484e334022d674bb81c8dfa73c4cc2f0b6844')
+
+prepare() {
+  cd "${srcdir}/${_pkgsrc}"
+  export RUSTUP_TOOLCHAIN=stable
+  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+  cd "${srcdir}/${_pkgsrc}"
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+  cargo build --frozen --release --all-features
+}
+
+check() {
+  cd "${srcdir}/${_pkgsrc}"
+  export RUSTUP_TOOLCHAIN=stable
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "${srcdir}/${_pkgsrc}"
+  install -Dm755 "target/release/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
+  install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
+  install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}