1 files changed, 73 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..0f2b1dcc7ec5
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,73 @@
+# Maintainer:  Gustavo Alvarez <sl1pkn07@gmail.com>
+
+_plug=neo_fft3dfilter
+pkgbase="foosynth-plugin-${_plug}-git"
+pkgname=("avisynth-plugin-${_plug}-git"
+         "vapoursynth-plugin-${_plug}-git"
+         )
+pkgver=r3.1.g7c235de
+pkgrel=1
+pkgdesc="Plugin for Vapoursynth/Avisynth: ${_plug} (Dual interface for Vapoursynth/Avisynth) (GIT version)"
+arch=('x86_64')
+url='https://github.com/HomeOfAviSynthPlusEvolution/neo_FFT3D.git'
+license=('GPL')
+makedepends=('git'
+             'cmake'
+             'fftw'
+             'intel-tbb'
+             'avisynthplus-git'
+             'vapoursynth'
+             )
+source=("${_plug}::git+https://github.com/HomeOfAviSynthPlusEvolution/neo_FFT3D.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${_plug}"
+  echo "$(git describe --first-parent --tags --always | tr - .)"
+}
+
+prepare() {
+  cd "${_plug}"
+  mkdir -p build
+
+  sed '1i#include <cpuid.h>' -i src/cpuid.cpp
+}
+
+build() {
+  cd "${_plug}/build"
+  cmake .. \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr
+
+  make
+}
+
+package_avisynth-plugin-neo_fft3dfilter-git() {
+  pkgdesc="Plugin for Avisynth: ${_plug} (GIT version)"
+  depends=('avisynthplus'
+           'fftw'
+           'intel-tbb'
+           )
+  provides=("avisynth-plugin-${_plug}")
+  conflicts=("avisynth-plugin-${_plug}")
+
+  install -Dm644 "${_plug}/build/libneo-fft3d.so" "${pkgdir}/usr/lib/avisynth/libneo-fft3d.so"
+  install -Dm644 "${_plug}/README.md" "${pkgdir}/usr/share/doc/avisynth/plugins/${_plug}/README.md"
+
+  install -Dm644 "${_plug}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_vapoursynth-plugin-neo_fft3dfilter-git() {
+  pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
+  depends=('vapoursynth'
+           'fftw'
+           'intel-tbb'
+           )
+  provides=("vapoursynth-plugin-${_plug}")
+  conflicts=("vapoursynth-plugin-${_plug}")
+
+  install -Dm644 "${_plug}/build/libneo-fft3d.so" "${pkgdir}/usr/lib/vapoursynth/libneo-fft3d.so"
+  install -Dm644 "${_plug}/README.md" "${pkgdir}/usr/share/doc/vapoursynth/plugins/${_plug}/README.md"
+
+  install -Dm644 "${_plug}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}