1 files changed, 51 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..a62ba605e66e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Arthur HUGEAT <hugeat dot arthur at gmail dot com>
+pkgname=gf-git
+pkgver=0.17.4.r30.g32d3c45
+pkgrel=1
+pkgdesc="Gamedev Framework (gf) is a framework to build 2D games in C++14. It is based on SDL and OpenGL ES 2.0, and presents an API that is very similar to the graphics module of SFML with additional features (development version)."
+arch=('x86_64' 'i686')
+url="https://gamedevframework.github.io/"
+license=('ZLIB')
+depends=('sdl2' 'boost-libs' 'freetype2' 'zlib' 'pugixml')
+makedepends=('boost' 'cmake' 'git')
+provides=('gf')
+conflicts=('gf')
+
+source=("git+https://github.com/GamedevFramework/gf")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${srcdir}/gf"
+  git describe --long --tags | sed -r 's/^v(.*)/\1/;s/([^-]*-g)/r\1/;s/-/./g'
+}
+
+prepare() {
+	cd "${srcdir}/gf"
+  git checkout develop
+	git submodule update --init
+}
+
+build() {
+  cd "${srcdir}/gf"
+  cmake -DGF_USE_EMBEDDED_LIBS=ON \
+        -DGF_BUILD_GAMES=OFF \
+        -DGF_BUILD_EXAMPLES=OFF \
+        -DGF_BUILD_DOCUMENTATION=OFF \
+        -DGF_SINGLE_COMPILTATION_UNIT=OFF \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        .
+  make
+}
+
+check() {
+  cd "${srcdir}/gf"
+  make test
+}
+
+package() {
+	cd "${srcdir}/gf"
+
+	make DESTDIR="$pkgdir/" install
+	mv ${pkgdir}/usr/share/doc/GF ${pkgdir}/usr/share/doc/gf
+	install -Dm644 LICENSE.txt ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt
+}