1 files changed, 92 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..0cf69688d4e4
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,92 @@
+# Maintainer: Jan Cholasta <grubber at grubber cz>
+
+_name=gzdoom
+pkgname=${_name}-legacy-git
+pkgver=g3.5.0_legacy+9+g169c41e14
+pkgrel=1
+pkgdesc='Advanced Doom source port with OpenGL support (git legacy version)'
+arch=('i686' 'x86_64')
+url='http://www.zdoom.org/'
+license=('BSD' 'custom:dumb' 'GPL3' 'LGPL3')
+depends=('hicolor-icon-theme'
+         'libgl'
+         'libgme'
+         'libjpeg'
+         'sdl2')
+makedepends=('cmake'
+             'desktop-file-utils'
+             'fluidsynth'
+             'git'
+             'gtk3')
+optdepends=('blasphemer-wad: Blasphemer (free Heretic) game data'
+            'chexquest3-wad: Chex Quest 3 game data'
+            'doom1-wad: Doom shareware game data'
+            'fluidsynth: FluidSynth MIDI device'
+            'freedm: FreeDM game data'
+            'freedoom1: Freedoom: Phase 1 game data'
+            'freedoom2: Freedoom: Phase 2 game data'
+            'gtk3: IWAD selection dialog'
+            'gxmessage: crash dialog (GNOME)'
+            'hacx-wad: HacX game data'
+            'harmony-wad: Harmony game data'
+            'heretic1-wad: Heretic shareware game data'
+            'hexen1-wad: Hexen demo game data'
+            'kdialog: crash dialog (KDE)'
+            'libsndfile: WAV/FLAC/OGG audio support'
+            'mpg123: MP3 audio support'
+            'openal: in-game sound'
+            'soundfont-fluid: FluidR3 soundfont for FluidSynth'
+            'strife0-wad: Strife shareware game data'
+            'square1-wad: The Adventures of Square, Episode 1 game data'
+            'urbanbrawl-wad: Urban Brawl: Action Doom 2 game data'
+            'xorg-xmessage: crash dialog (other)')
+provides=("${_name}")
+conflicts=("${_name}")
+source=("${_name}::git://github.com/drfrag666/${_name}.git#branch=legacy"
+        "${_name}.desktop"
+        '0001-Fix-soundfont-search-path.patch')
+sha256sums=('SKIP'
+            '59122e670f72aa2531aff370e7aaab2d886a7642e79e91f27a533d3b4cad4f6d'
+            'b0e621a39e0a050ce119fb4bea888afc7a02039ee9f37a2a5b518e4fe924b3f1')
+
+pkgver() {
+    cd $_name
+
+    git describe --tags --match '[Gg]*_legacy' | tr - +
+}
+
+prepare() {
+    cd $_name
+
+    patch -p1 -i"$srcdir"/0001-Fix-soundfont-search-path.patch
+}
+
+build() {
+    cd $_name
+
+    cmake -DCMAKE_BUILD_TYPE=Release \
+          -DCMAKE_C_FLAGS="$CFLAGS -DSHARE_DIR=\\\"/usr/share/$_name\\\"" \
+          -DCMAKE_CXX_FLAGS="$CXXFLAGS -DSHARE_DIR=\\\"/usr/share/$_name\\\"" \
+          -DCMAKE_EXE_LINKER_FLAGS="$LDFLAGS -Wl,-z,noexecstack" \
+          -DCMAKE_INSTALL_PREFIX=/usr \
+          -DINSTALL_PATH=bin \
+          -DINSTALL_PK3_PATH=share/$_name \
+          .
+    make
+}
+
+package() {
+    cd $_name
+
+    make install DESTDIR="$pkgdir"
+    install -D -m644 soundfonts/gzdoom.sf2 \
+            "$pkgdir"/usr/share/$_name/soundfonts/gzdoom.sf2
+
+    desktop-file-install --dir="$pkgdir"/usr/share/applications \
+                         "$srcdir"/${_name}.desktop
+    install -D -m644 src/posix/zdoom.xpm \
+            "$pkgdir"/usr/share/icons/hicolor/256x256/apps/${_name}.xpm
+
+    install -d "$pkgdir"/usr/share/licenses
+    ln -s /usr/share/doc/$_name/licenses "$pkgdir"/usr/share/licenses/$pkgname
+}