1 files changed, 38 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..8d9220ac2cd9
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: seth <getchoo at tuta dot io>
+
+pkgname=hiccup-git
+pkgver=r13.3b376cd
+pkgrel=1
+pkgdesc="a python script to help keep you up to date"
+arch=(any)
+url="https://github.com/getchoo/hiccup"
+license=('MIT')
+depends=('python' 'xdg-user-dirs')
+makedepends=('git' 'python-build' 'python-installer'
+             'python-wheel' 'python-setuptools')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("${pkgname%-git}::git+$url.git#branch=main")
+sha256sums=('SKIP')
+
+
+pkgver() {
+  cd "$srcdir/${pkgname%-git}"
+
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "$srcdir/${pkgname%-git}"
+
+  python -m build --wheel --no-isolation
+}
+
+package() {
+  cd "$srcdir/${pkgname%-git}"
+
+  python -m installer --compile-bytecode=1 --destdir="$pkgdir" dist/*.whl
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# nvim: ts=2 sw=2 et: