1 files changed, 36 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..a34f5efd6323
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Josip Ponjavic <josipponjavic at gmail dot com>
+
+pkgname=i3status-rust-git
+pkgver=0.1.0.r275.g6073151
+pkgrel=1
+pkgdesc='Very resourcefriendly and feature-rich replacement for i3status, written in pure Rust'
+arch=('i686' 'x86_64')
+url='https://github.com/greshake/i3status-rust'
+license=('GPL3')
+depends=('dbus')
+makedepends=('cargo' 'git')
+optdepends=('alsa-utils: For volume block'
+            'lm_sensors: For temperature block')
+provides=("${pkgname%-*}")
+conflicts=("${pkgname%-*}")
+install="${pkgname%-*}.install"
+source=("git+$url")
+sha1sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-*}"
+  echo $(grep '^version =' Cargo.toml|head -n1|cut -d\" -f2).r$(git rev-list --count HEAD).g$(git describe --always)
+}
+
+build() {
+  cd "${pkgname%-*}"
+  cargo build --release
+}
+
+package() {
+  cd "${pkgname%-*}"
+  install -Dm755 target/release/i3status-rs "$pkgdir/usr/bin/i3status-rs"
+  install -Dm644 example_config.toml "$pkgdir/usr/share/doc/${pkgname%-*}/examples/example_config.toml"
+  install -Dm644 example_icon.toml "$pkgdir/usr/share/doc/${pkgname%-*}/examples/example_icon.toml"
+  install -Dm644 example_theme.toml "$pkgdir/usr/share/doc/${pkgname%-*}/examples/example_theme.toml"
+}