1 files changed, 58 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..06a015def4a4
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,58 @@
+# Maintainer: Michael Darr <michael.e.darr@gmail.com>
+
+_pkgname='insomnia'
+pkgname="$_pkgname-git"
+pkgver="2020.4.0_alpha.3"
+pkgrel=1
+pkgdesc='HTTP and GraphQL client for developers'
+url="https://github.com/Kong/insomnia"
+arch=('x86_64' 'i686')
+license=('MIT')
+depends=(
+    'electron'
+    'jq'
+    'npm'
+)
+makedepends=(
+    'git'
+    'nvm'
+)
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=("$_pkgname::git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    jq -r .version "$srcdir/$_pkgname/packages/insomnia-app/config/config.core.json" | tr '-' '_'
+}
+
+build() {
+	# Use node 12
+	local node_version='12'
+	export npm_config_cache="$srcdir/npm_cache"
+	local npm_prefix=$(npm config get prefix)
+	npm config delete prefix
+	source /usr/share/nvm/init-nvm.sh
+	nvm install "$node_version" && nvm use "$node_version"
+
+    # Run the build
+    cd "$srcdir/$_pkgname"
+    npm run bootstrap
+    GITHUB_REF=core@$(jq -r .version "packages/insomnia-app/config/config.core.json") npm run app-package
+
+	# Restore node config
+	npm config set prefix "$npm_prefix"
+	nvm unalias default
+}
+
+package() {
+    # Set up package directories
+    install -d ${pkgdir}/{opt,usr/bin}
+
+    # Copy built files into the package
+    cd $srcdir/$_pkgname/packages/insomnia-app/dist/linux-unpacked
+    find . -type f -exec install -Dm 755 "{}" "$pkgdir/opt/$_pkgname/{}" \;
+
+    # Symlink the executable path into the package
+    ln -s /opt/$_pkgname/$_pkgname $pkgdir/usr/bin/$_pkgname
+}