1 files changed, 47 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..221df95c11f4
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
+
+pkgname=jemalloc-git
+pkgver=5.0.0.r4.g84f6c2ca
+pkgrel=1
+pkgdesc="General purpose malloc implementation"
+arch=('i686' 'x86_64')
+url="http://jemalloc.net/"
+license=('BSD')
+depends=('glibc')
+makedepends=('git' 'docbook-xsl')
+optdepends=('perl: for running jeprof')
+provides=('jemalloc')
+conflicts=('jemalloc')
+source=("git+https://github.com/jemalloc/jemalloc.git")
+sha256sums=('SKIP')
+
+
+pkgver() {
+  cd "jemalloc"
+
+  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "jemalloc"
+
+  _xslroot="/usr/share/xml/docbook/xsl-stylesheets-$(pacman -Q docbook-xsl | cut -d ' ' -f 2 | cut -d '-' -f 1)"
+  ./autogen.sh --prefix="/usr" --with-xslroot="$_xslroot"
+  make
+}
+
+check() {
+  cd "jemalloc"
+
+  make check
+}
+
+package() {
+  cd "jemalloc"
+
+  make dist
+  make DESTDIR="$pkgdir" install
+  install -Dm644 "COPYING" "$pkgdir/usr/share/licenses/jemalloc/COPYING"
+
+  find "$pkgdir" -name \*.a -type f -exec chmod 644 '{}' \;
+}