1 files changed, 40 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..6083db83f031
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: Antonio Rojas <arojas@archlinux.org>
+
+_gitname=kcalutils
+pkgname=$_gitname-git
+pkgver=r276.fba760a
+pkgrel=1
+pkgdesc="The KDE calendar utility library"
+arch=('i686' 'x86_64')
+url="https://projects.kde.org/projects/kde/pim/$_gitname"
+license=('LGPL')
+depends=('kcalcore-git' 'kidentitymanagement-git')
+makedepends=('extra-cmake-modules-git' 'git' 'python' 'boost')
+conflicts=("$_gitname")
+provides=("$_gitname")
+source=("git://anongit.kde.org/$_gitname.git")
+md5sums=('SKIP')
+
+pkgver() {
+  cd $_gitname
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$_gitname \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}