1 files changed, 45 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..8622aad42781
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: Martin
+
+_module=libs
+pkgname=kde2-kde${_module}-git
+pkgver=2.2.2.r23846.c22d02e13
+pkgrel=1
+pkgdesc="Historical copy of the $_module module of KDE 2, adapted to compile on modern systems"
+arch=(i686 x86_64)
+url="https://github.com/sandsmark/kde${_module}"
+license=("GPL2")
+groups=(kde2)
+makedepends=(cmake git)
+provides=(kde2-kde${_module})
+conflicts=(kde2-kde${_module})
+
+# Mirror
+source=("git+https://github.com/sandsmark/kde${_module}.git")
+
+md5sums=('SKIP')
+
+pkgver() {
+  cd kde${_module}
+  printf "2.2.2.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  if [[ -d build ]]; then
+    rm -rf build && mkdir build
+  else
+    mkdir build
+  fi
+}
+
+build() {
+  cd build
+  cmake "$srcdir"/kde${_module} -DCMAKE_INSTALL_PREFIX=/usr -DKDEDIR=/usr/
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir/" install
+  cd "$srcdir"/kde${_module}
+  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
+}