1 files changed, 89 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..a121df762672
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,89 @@
+# Maintainer: Jonathon Fernyhough <jonathon"manjaro+org>
+# Contributor: Sam Guymer <sam at guymer dot me>
+
+# This PKGBUILD adapted from zulu-11-bin
+
+_jdkname=liberica-jdk-full
+pkgname="${_jdkname}-bin"
+_java_ver=13
+pkgver=13.0.2+9
+pkgrel=1
+pkgdesc='BellSoft builds of OpenJDK are fully certified and 100% open source Java Development Kits (JDKs) for all Java development and production workloads. Full version includes OpenJFX.'
+arch=(aarch64 armv7h armv8h x86_64)
+url='https://bell-sw.com/'
+license=('custom')
+depends=('java-environment-common=3' 'java-runtime-common>=3' 'ca-certificates-utils')
+optdepends=(ffmpeg freetype2 gtk2 gtk3 libnet)
+provides=(
+  "java-environment=$_java_ver"
+  "java-environment-openjdk=$_java_ver"
+  "java-runtime-headless=$_java_ver"
+  "java-runtime-headless-openjdk=$_java_ver"
+  "java-runtime=$_java_ver"
+  "java-runtime-openjdk=$_java_ver"
+  "liberica-jdk-bin=$pkgver"
+  "liberica-jdk-lite-bin=$pkgver"
+  "liberica-jre-bin=$pkgver"
+  "liberica-jre-full-bin=$pkgver"
+)
+install=$_jdkname.install
+
+backup=(etc/${_jdkname}/logging.properties
+        etc/${_jdkname}/management/jmxremote.access
+        etc/${_jdkname}/management/jmxremote.password.template
+        etc/${_jdkname}/management/management.properties
+        etc/${_jdkname}/net.properties
+        etc/${_jdkname}/security/java.policy
+        etc/${_jdkname}/security/java.security
+        etc/${_jdkname}/security/policy/README.txt
+        etc/${_jdkname}/security/policy/limited/default_US_export.policy
+        etc/${_jdkname}/security/policy/limited/default_local.policy
+        etc/${_jdkname}/security/policy/limited/exempt_local.policy
+        etc/${_jdkname}/security/policy/unlimited/default_US_export.policy
+        etc/${_jdkname}/security/policy/unlimited/default_local.policy
+        etc/${_jdkname}/sound.properties)
+
+source_aarch64=(https://download.bell-sw.com/java/$pkgver/bellsoft-jdk$pkgver-linux-aarch64-full.tar.gz)
+source_armv7h=(https://download.bell-sw.com/java/$pkgver/bellsoft-jdk$pkgver-linux-arm32-vfp-hflt-full.tar.gz)
+source_armv8h=(${source_armv7h[@]})
+source_x86_64=(https://download.bell-sw.com/java/$pkgver/bellsoft-jdk$pkgver-linux-amd64-full.tar.gz)
+
+# Upstream-provided
+sha1sums_aarch64=('d51f703a73e81289d464a64ccabb8ce65888f3bd')
+sha1sums_armv7h=('86dc674fab129d50aec91e1d0a1a55587a945d34')
+sha1sums_armv8h=('86dc674fab129d50aec91e1d0a1a55587a945d34')
+sha1sums_x86_64=('4ffcb6bb9d75070907f65453b503f81f66926beb')
+
+_jvmdir="/usr/lib/jvm/${_jdkname}"
+
+package() {
+  cd jdk-${pkgver/+*/}
+
+  install -dm 755 "${pkgdir}/${_jvmdir}"
+  cp -a . "${pkgdir}/${_jvmdir}/"
+
+  # copied from java11-openjdk
+
+  # Conf
+  install -dm 755 "${pkgdir}/etc"
+  cp -r conf "${pkgdir}/etc/${_jdkname}"
+  rm -rf "${pkgdir}/${_jvmdir}/conf"
+  ln -s "/etc/${_jdkname}" "${pkgdir}/${_jvmdir}/conf"
+
+  # Legal
+  install -dm 755 "${pkgdir}/usr/share/licenses"
+  cp -r legal "${pkgdir}/usr/share/licenses/${_jdkname}"
+  rm -rf "${pkgdir}/${_jvmdir}/legal"
+  ln -s "/usr/share/licenses/${_jdkname}" "${pkgdir}/${_jvmdir}/legal"
+
+  # Man pages
+  for f in man/man1/*; do
+    install -Dm 644 "${f}" "${pkgdir}/usr/share/${f/\.1/-$_jdkname.1}"
+  done
+  rm -rf "${pkgdir}/${_jvmdir}/man"
+  ln -s /usr/share/man "${pkgdir}/${_jvmdir}/man"
+
+  # Link JKS keystore from ca-certificates-utils
+  rm -f "${pkgdir}/${_jvmdir}/lib/security/cacerts"
+  ln -sf /etc/ssl/certs/java/cacerts "${pkgdir}/${_jvmdir}/lib/security/cacerts"
+}