1 files changed, 48 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..7bca75b67c1e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Andy Weidenbaum <archbaum@gmail.com>
+
+pkgname=libmarpa
+pkgver=8.3.0
+pkgrel=1
+pkgdesc="Marpa parse engine C library"
+arch=('i686' 'x86_64')
+makedepends=('autoconf' 'automake' 'libtool' 'make' 'perl' 'texlive-bin')
+url="https://github.com/jeffreykegler/libmarpa"
+license=('MIT')
+source=($pkgname-$pkgver::git+https://github.com/jeffreykegler/libmarpa)
+sha256sums=('SKIP')
+
+prepare() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  msg2 'Preparing distribution...'
+  make dist
+}
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver/dist"
+
+  msg2 'Building...'
+  ./configure \
+    --prefix=/usr \
+    --sbindir=/usr/bin \
+    --libexecdir=/usr/lib/libmarpa \
+    --sysconfdir=/etc \
+    --sharedstatedir=/usr/share/libmarpa \
+    --localstatedir=/var/lib/libmarpa \
+    --with-gnu-ld
+  make
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver/dist"
+
+  msg2 'Installing license...'
+  install -Dm 644 AUTHORS COPYING{,.LESSER} \
+          -t "$pkgdir/usr/share/licenses/libmarpa"
+
+  msg2 'Installing documentation...'
+  install -Dm 644 README{,.INSTALL} -t "$pkgdir/usr/share/doc/libmarpa"
+
+  msg2 'Installing...'
+  make DESTDIR="$pkgdir" install
+}