1 files changed, 35 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..9402049b40a9
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,35 @@
+# Maintainer: David Parrish <daveparrish@tutanota.com>
+
+pkgname=list-all-systemd-timers-git
+pkgver=r5.175bcac
+pkgrel=1
+pkgdesc="Prints all systemd timers to stdout"
+arch=('i686' 'x86_64')
+makedepends=('git' 'ghc')
+url="https://github.com/dmp1ce/list-all-systemd-timers"
+license=('custom:Unlicense')
+options=('strip')
+source=("${pkgname}::git+https://github.com/dmp1ce/list-all-systemd-timers.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname}"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  msg2 'Building...'
+  cd "${pkgname}"
+  ghc --make list-all-systemd-timers.hs
+}
+
+package() {
+  cd "${pkgname}"
+
+  msg2 'Installing license...'
+  install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/list-all-systemd-timers"
+
+  msg2 'Installing...'
+  mkdir -p "$pkgdir/usr/bin"
+  install -Dm 755 list-all-systemd-timers -t "$pkgdir/usr/bin"
+}