1 files changed, 33 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..1dbbc110bbc7
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,33 @@
+pkgname=mingw-w64-abseil-cpp
+pkgver=20230125.3
+pkgrel=1
+pkgdesc='Collection of C++ library code designed to augment the C++ standard library (mingw-w64)'
+arch=('any')
+url='https://abseil.io'
+license=('Apache')
+depends=('mingw-w64-crt')
+makedepends=('mingw-w64-cmake')
+options=('!buildflags' '!strip' 'staticlibs')
+source=("https://github.com/abseil/abseil-cpp/archive/$pkgver/abseil-cpp-$pkgver.tar.gz")
+sha256sums=('5366d7e7fa7ba0d915014d387b66d0d002c03236448e1ba9ef98122c13b35c36')
+
+_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
+
+build() {
+  cd "${srcdir}/abseil-cpp-$pkgver"
+  for _arch in ${_architectures}; do
+    mkdir -p build-${_arch} && pushd build-${_arch}
+    ${_arch}-cmake  ..
+    make
+    popd
+  done
+}
+
+package() {
+  for _arch in $_architectures; do
+    cd "$srcdir"/abseil-cpp-$pkgver/build-${_arch}
+    make install DESTDIR="$pkgdir"
+    ${_arch}-strip --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
+    ${_arch}-strip -g "$pkgdir"/usr/${_arch}/lib/*.a
+  done
+}