1 files changed, 47 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b232886faa0e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: 
+# Contributor: 
+
+pkgname=mingw-w64-dbh
+pkgver=5.0.20
+pkgrel=2
+pkgdesc="GNU DBH database library (mingw-w64)"
+url="http://www.gnu.org/software/libdbh/"
+license=('GPL')
+arch=('any')
+depends=('mingw-w64-crt')
+makedepends=('mingw-w64-gcc' 'mingw-w64-gettext')
+source=("https://sourceforge.net/projects/dbh/files/dbh/${pkgver}/libdbh2-${pkgver}.tar.gz/download")
+options=('staticlibs' '!buildflags' '!strip')
+md5sums=('b06b504b694e5182f855d642e7dd31af')
+_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
+
+prepare() {
+  cd "${srcdir}/libdbh2-${pkgver}"
+
+  autoreconf -vfi
+}
+
+build() {
+  cd "${srcdir}/libdbh2-${pkgver}"
+  for _arch in ${_architectures}; do
+    unset LDFLAGS
+    mkdir -p "build-${_arch}" && pushd "build-${_arch}"
+
+    ../configure \
+              --prefix=/usr/${_arch} \
+              --host=${_arch}
+    make
+    popd
+  done
+}
+
+package() {
+  for _arch in ${_architectures}; do
+    cd "${srcdir}/libdbh2-${pkgver}/build-$_arch"
+    make DESTDIR="$pkgdir" install
+    rm -r "$pkgdir"/usr/${_arch}/share
+    ${_arch}-strip --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
+    ${_arch}-strip -g "$pkgdir"/usr/${_arch}/lib/*.a
+
+  done
+}