1 files changed, 45 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..56c7fd1fae80
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: lantw44 at gmail dot com
+
+pkgname=mingw-w64-libepoxy
+pkgver=1.2
+pkgrel=1
+pkgdesc="A library for handling OpenGL function pointer management for you (mingw-w64)"
+arch=(any)
+url="https://github.com/anholt/libepoxy"
+license=('MIT')
+makedepends=(
+  'mingw-w64-gcc'
+  'mingw-w64-configure'
+  'xorg-util-macros' 
+  'python')
+depends=(
+  'mingw-w64-crt')
+options=(!strip !buildflags staticlibs)
+source=(libepoxy-${pkgver}.tar.gz::https://github.com/anholt/libepoxy/archive/v${pkgver}.tar.gz)
+sha256sums=('42c328440f60a5795835c5ec4bdfc1329e75bba16b6e22b3a87ed17e9679e8f6')
+
+_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
+
+build() {
+  cd "${srcdir}/libepoxy-${pkgver}"
+  NOCONFIGURE=1 ./autogen.sh
+  for _arch in ${_architectures}; do
+    mkdir -p "build-${_arch}"
+    cd "build-${_arch}"
+    ${_arch}-configure
+    make
+    cd ..
+  done
+}
+
+package() {
+  cd "${srcdir}/libepoxy-${pkgver}"
+  for _arch in ${_architectures}; do
+    cd "build-${_arch}"
+    make DESTDIR="$pkgdir" install
+    find "$pkgdir/usr/${_arch}" -name '*.exe' -o -name '*.bat' -o -name '*.def' -o -name '*.exp' -o -name '*.manifest' | xargs -rtl1 rm
+    find "$pkgdir/usr/${_arch}" -name '*.dll' | xargs -rtl1 ${_arch}-strip -x
+    find "$pkgdir/usr/${_arch}" -name '*.a' -o -name '*.dll' | xargs -rtl1 ${_arch}-strip -g
+    cd ..
+  done
+}