1 files changed, 46 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..6a5d3023d70d
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Serge K <arch@phnx47.net>
+
+# For Issues, Pull Requests
+# https://github.com/phnx47/pkgbuilds
+
+pkgname=moon
+pkgdesc='Task runner and repo management tool for the web ecosystem'
+pkgver=1.13.4
+pkgrel=1
+license=('MIT')
+url='https://github.com/moonrepo/moon'
+arch=('x86_64' 'aarch64')
+makedepends=('cargo')
+options=('!lto')
+_sha='8d819763db74cefb76608fdf2eb49ca4f7c8d63b'
+_short_sha="${_sha::7}"
+source=("${pkgname}-${pkgver}-${_short_sha}.tar.gz::https://api.github.com/repos/moonrepo/moon/tarball/${_sha}")
+sha256sums=('04322a8ed49fff62c9191b4821b27b7cdf216d4d5fcda83acde1a4812bd3a9ea')
+
+prepare() {
+  cd "moonrepo-moon-${_short_sha}"
+  export RUSTUP_TOOLCHAIN="stable"
+  cargo fetch --locked --target "${CARCH}-unknown-linux-gnu"
+}
+
+build() {
+  cd "moonrepo-moon-${_short_sha}"
+  export RUSTUP_TOOLCHAIN="stable"
+  export CARGO_TARGET_DIR="target"
+  cargo build --release --frozen
+
+  mkdir -p completions
+  "./target/release/${pkgname}" completions --shell bash >"completions/bash"
+  "./target/release/${pkgname}" completions --shell zsh >"completions/zsh"
+  "./target/release/${pkgname}" completions --shell fish >"completions/fish"
+}
+
+package() {
+  cd "moonrepo-moon-${_short_sha}"
+  install -Dm 755 "target/release/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
+  install -Dm 644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+
+  install -Dm 644 "completions/bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
+  install -Dm 644 "completions/zsh" "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
+  install -Dm 644 "completions/fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
+}