1 files changed, 51 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..e92eaacb12d5
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Daniel Egeberg <daniel.egeberg@gmail.com>
+pkgname="nzbhydra"
+pkgver=0.0.1a90
+pkgrel=1
+pkgdesc="Meta search for NZB indexers"
+arch=('any')
+url="https://github.com/theotherp/nzbhydra"
+license=('Apache')
+depends=('python2')
+optdepends=('python2-lxml: faster result processing')
+conflicts=('nzbhydra-git')
+install='nzbhydra.install'
+provides=('nzbhydra')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/theotherp/nzbhydra/archive/$pkgver.tar.gz"
+        "nzbhydra.sh"
+        "nzbhydra.service"
+        "nzbhydra.install")
+
+sha256sums=('2c5dec21b85b69381cd3fa9d6e7c1d30d09e2b49a1396d734953d93874caae36'
+            '91552953d0d956101136cd3165f217de4d14eb65042b7dd3e9a09c8657319436'
+            '9035c3c2a7d773ddadefb207cc0690629283f60903189ad595dd8de098c4457f'
+            '4419c7faed911a03ea0c9ccafa69607d2038cf49a508aa5595d9732146204649')
+
+package() {
+    cd "${srcdir}"
+
+    install -d -m 755 "${pkgdir}/usr/lib/nzbhydra"
+    cp -dpr --no-preserve=ownership "${srcdir}/nzbhydra-${pkgver}/"* "${pkgdir}/usr/lib/nzbhydra"
+
+    msg2 "Precompiling python files"
+    python2 -m compileall -q "${pkgdir}/usr/lib/nzbhydra"
+
+    install -D -m 755 "${srcdir}/nzbhydra.sh" "${pkgdir}/usr/bin/nzbhydra"
+
+    install -d -m 755 "${pkgdir}/var/lib/nzbhydra"
+
+    mkdir -m 755 "${pkgdir}/var/lib/nzbhydra/flask_session"
+    touch "${pkgdir}/var/lib/nzbhydra/nzbhydra.log"
+    touch "${pkgdir}/var/lib/nzbhydra/nzbhydra.pid"
+
+    chmod 644 "${pkgdir}/var/lib/nzbhydra/nzbhydra.log"
+    chmod 644 "${pkgdir}/var/lib/nzbhydra/nzbhydra.pid"
+
+    ln -s "../../../var/lib/nzbhydra/nzbhydra.log" "${pkgdir}/usr/lib/nzbhydra/nzbhydra.log"
+    ln -s "../../../var/lib/nzbhydra/nzbhydra.pid" "${pkgdir}/usr/lib/nzbhydra/nzbhydra.pid"
+    ln -s "../../../var/lib/nzbhydra/flask_session" "${pkgdir}/usr/lib/nzbhydra/flask_session"
+
+    install -d -m 750 "${pkgdir}/etc/nzbhydra"
+
+    install -D -m 644 "${srcdir}/nzbhydra.service" "${pkgdir}/usr/lib/systemd/system/nzbhydra.service"
+}