1 files changed, 38 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..5e52783e3c75
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Benjamin Klettbach <b dot klettbach at gmail dot com >
+# Contributor: ArcticVanguard <LideEmily at gmail dot com>
+# Contributor: ledti <antergist at gmail dot com>
+
+pkgname=obs-studio-git
+_pkgname=obs-studio
+pkgver=0.11.0.r1.g91bfb53
+pkgrel=1
+pkgdesc="Free and open source software for video recording and live streaming."
+arch=('i686' 'x86_64')
+url="https://github.com/jp9000/obs-studio"
+license=('GPL2')
+depends=('ffmpeg' 'jansson' 'libxinerama' 'libxkbcommon-x11' 'qt5-x11extras')
+makedepends=('cmake' 'git' 'libfdk-aac' 'libxcomposite' 'x264')
+optdepends=('libfdk-aac: FDK AAC codec support'
+            'libxcomposite: XComposite capture support')
+provides=('obs-studio')
+conflicts=('obs-studio')
+source=("$_pkgname::git://github.com/jp9000/obs-studio.git#branch=master")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/$_pkgname"
+  git describe --long --tags | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "$srcdir/$_pkgname"
+  mkdir -p "build"
+  cd "build"
+  cmake -DCMAKE_INSTALL_PREFIX="/usr" -DOBS_VERSION_OVERRIDE=$pkgver ..
+  make -j`nproc`
+}
+
+package() {
+  cd "$srcdir/$_pkgname/build"
+  make DESTDIR="$pkgdir" install
+}