1 files changed, 39 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..eda0e547d556
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: Morgenstern <charles [at] charlesbwise [dot] com>
+# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+
+pkgname=parcellite-git
+pkgver=1.2.1.r11.fa54161
+pkgrel=1
+pkgdesc="Lightweight GTK+ clipboard manager (git version)"
+arch=('x86_64')
+url="https://github.com/rickyrockrat/parcellite"
+license=('GPL3')
+depends=('gtk2')
+makedepends=('intltool' 'git')
+optdepends=('xdotool: auto-paste support')
+conflicts=('parcellite')
+provides=('parcellite')
+source=("$pkgname"::'git://github.com/rickyrockrat/parcellite')
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/$pkgname"
+  git describe --long --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd "$srcdir/$pkgname"
+  autoreconf -i
+}
+
+build() {
+  cd "$srcdir/$pkgname"
+  ./configure --prefix=/usr --sysconfdir=/etc
+  make
+}
+
+package() {
+  cd "$srcdir/$pkgname"
+  make DESTDIR="$pkgdir" install
+}