1 files changed, 48 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..85f1d8045b14
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Martchus <martchus@gmx.net>
+
+# All my PKGBUILDs are managed at https://github.com/Martchus/PKGBUILDs where
+# you also find the URL of a binary repository.
+
+_reponame=passwordfile
+pkgname=passwordfile-git
+_name=${pkgname%-git}
+pkgver=45.2b28fbcc66
+pkgrel=1
+arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
+pkgdesc='C++ library to read/write passwords from/to encrypted files using AES-256-CBC via OpenSSL'
+license=('GPL')
+depends=('c++utilities-git' 'openssl')
+optdepends=("$_name-doc: API documentation")
+makedepends=('cmake' 'git')
+checkdepends=('cppunit')
+#provides=("${_name}")
+conflicts=("${_name}")
+install=
+url="https://github.com/Martchus/${_reponame}"
+source=("${_reponame}::${MARTCHUS_GIT_URL_PREFIX:-git://github.com/Martchus}/${_reponame}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
+  echo "$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
+  cmake \
+    -DCMAKE_BUILD_TYPE:STRING='Release' \
+    -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
+    -DBUILD_SHARED_LIBS:BOOL=ON \
+    .
+  make
+}
+
+check() {
+  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
+  make check
+}
+
+package() {
+  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
+  make DESTDIR="${pkgdir}" install
+}