1 files changed, 51 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..2bf0f26e2436
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Evgeniy Alekseev <arcanis at archlinux dot org>
+# Contributor: Tom <reztho at archlinux dot us>
+
+pkgname=pdfsam
+pkgver=4.2.0
+pkgrel=1
+pkgdesc="A free open source tool to split and merge pdf documents"
+arch=('any')
+url="https://www.pdfsam.org/"
+license=('AGPL3')
+depends=('hicolor-icon-theme' 'java-environment>=11' 'sh')
+makedepends=('desktop-file-utils' 'gendesk')
+source=("https://github.com/torakiki/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}-linux.zip"
+        "pdfsam")
+
+prepare() {
+  # create *.desktop file
+  gendesk -f -n \
+          --pkgname="${pkgname}" \
+          --pkgdesc="${pkgdesk}" \
+          --name="PDFsam" \
+          --categories="Office"
+
+  # extract icons
+  bsdtar -xf ${pkgname}-${pkgver}-linux/pdfsam-basic-${pkgver}.jar images/basic
+}
+
+package() {
+  install -dm755 "${pkgdir}/usr/share/java/${pkgname}/lib"
+  install -Dm644 "${pkgname}-${pkgver}-linux/pdfsam-basic-${pkgver}.jar" \
+                 "${pkgdir}/usr/share/java/${pkgname}/"
+  install -Dm644 "${pkgname}-${pkgver}-linux/lib/"* \
+                 "${pkgdir}/usr/share/java/${pkgname}/lib"
+  install -Dm755 "${pkgname}-${pkgver}-linux/bin/pdfsam.sh" \
+                 "${pkgdir}/usr/share/java/${pkgname}/bin/pdfsam.sh"
+
+  # exec
+  install -Dm755 "pdfsam" "${pkgdir}/usr/bin/pdfsam"
+
+  # icons
+  for _icon in 16 24 32 48 64 96 128 256 512; do
+      install -Dm644 images/basic/${_icon}x${_icon}.png \
+        "${pkgdir}/usr/share/icons/hicolor/${_icon}x${_icon}/apps/${pkgname}.png"
+  done
+
+  # desktop
+  install -Dm644 "${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
+}
+
+sha512sums=('26ec8f1c554c4b308c0fbc27d46c25c922fe0f6d128feb5156bdbb890646cf270a4b0dd54efe18e52775b90fcefb5e7748c9bd2bf131151c5f5a40711766c84a'
+            'c0d8665e8f0a82e539cd70972f95f819d13b10166f1e4bb04d032d108ef5de45fe77f8716e8e2f0fa129e7042907928bde1d947cc54f691aa6d87a76dfaa10c1')