1 files changed, 32 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..4575b85dc7c6
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,32 @@
+# Maintainer: FichteFoll <fichtefoll2@googlemail.com>
+
+_pkgbase=python-dbussy
+# _name=${_pkgbase#python-}
+pkgname="${_pkgbase}-git"
+pkgver=r447.cc89ae8
+pkgrel=1
+pkgdesc="Python binding for D-Bus using asyncio"
+arch=(any)
+url="https://github.com/ldo/dbussy"
+license=('LGPL')
+depends=('python')
+makedepends=('git' 'python-setuptools')
+provides=("${_pkgbase}")
+conflicts=("${_pkgbase}")
+source=("${_pkgbase}::git+https://github.com/ldo/dbussy")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "${srcdir}/${_pkgbase}"
+    (
+        set -o pipefail
+        git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
+        printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+    )
+}
+
+package() {
+    cd "${srcdir}/${_pkgbase}"
+    python setup.py install --root="$pkgdir/" --optimize=1
+    install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}