1 files changed, 35 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..951524f85f61
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,35 @@
+# Maintainer: Andrew O'Neill <andrew at meanjollies dot com>
+
+pkgname=python-oci
+_pyname=oci-python-sdk
+pkgver=1.4.4
+pkgrel=1
+pkgdesc='Python SDK for Oracle Cloud Infrastructure'
+arch=('any')
+url="https://github.com/oracle/oci-python-sdk"
+license=('Apache')
+depends=('python' 'python-pyjwt' 'python-dateutil' 'python-certifi' 'python-cryptography' 'python-idna' 'python-pyopenssl' 'python-pytz' 'python-requests' 'python-six')
+makedepends=('python-setuptools')
+source=("${url}/archive/v${pkgver}.tar.gz"
+        "${pkgname}.patch")
+sha256sums=('7c371b8e443d81d445308443954690a207ba50cf0b3aa8c45604511c20a7d46f'
+            'a79054a7ff2505bee403f91bdd7b4217e8704df0ce19f7eb9c0c249d77abefad')
+
+prepare() {
+  cd "${_pyname}-${pkgver}"
+
+  patch -p1 -i ../${pkgname}.patch
+}
+
+build() {
+  cd "${_pyname}-${pkgver}"
+
+  python setup.py build
+}
+
+package() {
+  cd "${_pyname}-$pkgver"
+
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}