1 files changed, 37 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..d1df42d9ba12
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: 0x9fff00 <0x9fff00+git@protonmail.ch>
+
+_name=PyMCTranslate
+_pkgname=python-${_name,,}
+pkgname=$_pkgname-git
+pkgver=r409.edd274e3
+pkgrel=1
+pkgdesc='A library of block mappings that can be used to convert from any Minecraft format into any other Minecraft format'
+arch=('any')
+url="https://github.com/gentlegiantJGC/$_name"
+license=('custom')
+depends=('python' 'python-numpy')
+makedepends=('git' 'python-setuptools')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+options=(!strip) # strip is extremely slow and there are no ELF files anyway
+source=("git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$_name"
+
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "$_name"
+
+  python setup.py build
+}
+
+package() {
+  cd "$_name"
+
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}