1 files changed, 36 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..fbf49b931440
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Josip Ponjavic <josipponjavic at gmail dot com>
+
+pkgname=qt5ct-svn
+pkgver=0.32.r406
+pkgrel=1
+pkgdesc="Qt5 Configuration Tool - svn version."
+arch=('i686' 'x86_64')
+url="http://qt-apps.org/content/show.php/Qt5+Configuration+Tool?content=168066"
+license=('BSD')
+depends=('qt5-svg')
+makedepends=('qt5-tools' 'subversion')
+conflicts=("${pkgname%-*}")
+provides=("${pkgname%-*}")
+install=${pkgname%-*}.install
+source=('qt5ct::svn://svn.code.sf.net/p/qt5ct/code/trunk/qt5ct')
+md5sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-*}"
+  major=$(grep 'define QT5CT_VERSION_MAJOR' src/qt5ct/qt5ct.h | awk '{print $3}')
+  minor=$(grep 'define QT5CT_VERSION_MINOR' src/qt5ct/qt5ct.h | awk '{print $3}')
+  local ver="$(svnversion)"
+  printf "%s.r%s" "$major"."$minor" "${ver//[[:alpha:]]}"
+}
+
+build() {
+  cd "${pkgname%-*}"
+  qmake-qt5 qt5ct.pro
+  make
+}
+
+package() {
+  cd "${pkgname%-*}"
+  make INSTALL_ROOT="$pkgdir" install
+  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}