1 files changed, 40 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..7ab1dd2af76d
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+
+_pkgname=escheR
+_pkgver=1.0.0
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="Unified multi-dimensional visualizations with Gestalt principles"
+arch=(any)
+url="https://bioconductor.org/packages/${_pkgname}"
+license=(MIT)
+depends=(
+  r-ggplot2
+  r-rlang
+  r-spatialexperiment
+  r-spatiallibd
+  r-summarizedexperiment
+)
+optdepends=(
+  r-biocstyle
+  r-knitr
+  r-rmarkdown
+  r-stexampledata
+)
+source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('df1ed86f7963992371c853e9b05284b7')
+sha256sums=('7db6d150e9654adfdd46871a50d8c24fbe808cf16b36ee9f77e3677cbbcff45a')
+
+build() {
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+
+  install -d "$pkgdir/usr/share/licenses/$pkgname"
+  ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
+}