1 files changed, 59 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..bccbfb5d9217
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,59 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+
+_pkgname=HiCDOC
+_pkgver=1.4.0
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="A/B compartment detection and differential analysis"
+arch=(x86_64)
+url="https://bioconductor.org/packages/${_pkgname}"
+license=(LGPL3)
+depends=(
+  r-biocgenerics
+  r-biocparallel
+  r-cowplot
+  r-data.table
+  r-genomeinfodb
+  r-genomicranges
+  r-ggplot2
+  r-gridextra
+  r-gtools
+  r-interactionset
+  r-multihiccompare
+  r-pbapply
+  r-rcpp
+  r-s4vectors
+  r-summarizedexperiment
+  r-zlibbioc
+  zlib
+)
+checkdepends=(
+  r-testthat
+)
+optdepends=(
+  r-biocmanager
+  r-biocstyle
+  r-knitr
+  r-rhdf5
+  r-rmarkdown
+  r-testthat
+)
+source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('334df180a7e5e2851bbf6724e8537ffd')
+sha256sums=('237724013ba999d39bc69394adc52b83bb29e9618b552bae00114aaa4653edf8')
+
+build() {
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+}