1 files changed, 50 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..9d00c135467c
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+
+_pkgname=readODS
+_pkgver=2.1.0
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="Read and Write ODS Files"
+arch=(x86_64)
+url="https://cran.r-project.org/package=${_pkgname}"
+license=(GPL3)
+depends=(
+  r-cellranger
+  r-readr
+  r-stringi
+  r-tibble
+  r-vctrs
+  r-zip
+)
+makedepends=(
+  r-cpp11
+)
+checkdepends=(
+  r-testthat
+)
+optdepends=(
+  r-covr
+  r-knitr
+  r-rmarkdown
+  r-spelling
+  r-testthat
+)
+source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('ebde6b50a9c615a5b3fb3217361d33d7')
+sha256sums=('3f3e557ac7cadeda4759c51f866ce9a942cb21a2b3dd24e55a082fc7d300d7fe')
+
+build() {
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+}