1 files changed, 32 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..e84bed9866c7
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,32 @@
+# Maintainer: "Amhairghin" Oscar Garcia Amor (https://ogarcia.me)
+
+pkgname=rlpcli
+pkgver=0.1.0
+pkgrel=1
+pkgdesc='CLI helper to get paswords and site settings directly from a LessPass server'
+arch=('arm' 'armv6h' 'armv7h' 'aarch64' 'i686' 'x86_64')
+url='https://github.com/ogarcia/rlpcli'
+license=('GPL3')
+depends=('gcc-libs' 'openssl')
+makedepends=('rust')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/ogarcia/${pkgname}/archive/${pkgver}.tar.gz")
+b2sums=('1307bba9332a0e51544242dfc868bd0fc1c3109340e5f2998e538ac5c7d5c502d7b790af17b60c3b80a3a8ae54dae0c05d4aca3b6b06994978e013c7260b7ebd')
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  cargo fetch --locked
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  cargo build --frozen --release --target-dir=target
+}
+
+package() {
+  # binary
+  install -Dm755 "${srcdir}/${pkgname}-${pkgver}/target/release/${pkgname}" \
+    "${pkgdir}/usr/bin/${pkgname}"
+  # readme
+  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/README.md" \
+    "${pkgdir}/usr/share/doc/${pkgname}/README.md"
+}