1 files changed, 79 insertions, 15 deletions
diff --git a/PKGBUILD b/PKGBUILD
index 18199b4f900f..03bda7c910ab 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,24 +1,88 @@
-# Maintainer: farwayer <farwayer@gmail.com>
+# Maintainer: Mario Finelli <mario at finel dot li>
+# Contributor: farwayer <farwayer@gmail.com>
 
 _gemname=digest-crc
 pkgname=ruby-${_gemname}
-pkgver=0.4.1
+pkgver=0.6.5
 pkgrel=1
-pkgdesc="Adds support for calculating Cyclic Redundancy Check (CRC) to the Digest module."
-arch=('any')
+pkgdesc="A Cyclic Redundancy Check (CRC) library for Ruby"
+arch=(x86_64)
+url=https://github.com/postmodern/digest-crc
+license=(MIT)
 depends=(ruby)
-url="https://rubygems.org/gems/${_gemname}"
-noextract=($_gemname-$pkgver.gem)
+checkdepends=(ruby-rspec ruby-simplecov ruby-yard)
+makedepends=(rubygems ruby-rdoc ruby-bundler ruby-rake ruby-rubygems-tasks)
 options=(!emptydirs)
-license=('MIT')
-source=(
-  "https://rubygems.org/downloads/${_gemname}-${pkgver}.gem"
-)
-sha256sums=('1494ee18bbb84a61828afe09616dc22c2b73a492b50b0f79334a85321db80823')
+source=(${url}/archive/v${pkgver}/$_gemname-$pkgver.tar.gz)
+sha256sums=('87e0ed5e6a4200b5df69b54f16e598b7d387f19b04fed352d22e8ded83b1205c')
+
+prepare() {
+  cd $_gemname-$pkgver
+
+  # we use a tarball, not a git checkout
+  sed -i 's/git ls-files/find/' ${_gemname}.gemspec
+
+  sed -i '/kramdown/d' Gemfile
+  sed -i '/github-markup/d' Gemfile
+}
+
+build() {
+  cd $_gemname-$pkgver
+  local _gemdir="$(gem env gemdir)"
+
+  # rake build:c_exts
+  gem build "${_gemname}.gemspec"
+
+  gem install \
+    --local \
+    --verbose \
+    --ignore-dependencies \
+    --no-user-install \
+    --install-dir "tmp_install/${_gemdir}" \
+    --bindir "tmp_install/usr/bin" \
+    "${_gemname}-${pkgver}.gem"
+
+  # remove unrepreducible files
+  rm --force --recursive --verbose \
+    "tmp_install/${_gemdir}/cache/" \
+    "tmp_install/${_gemdir}/gems/${_gemname}-${pkgver}/vendor/" \
+    "tmp_install/${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"
+
+  find "tmp_install/${_gemdir}/gems/" \
+    -type f \
+    \( \
+      -iname "*.o" -o \
+      -iname "*.c" -o \
+      -iname "*.so" -o \
+      -iname "*.time" -o \
+      -iname "gem.build_complete" -o \
+      -iname "Makefile" \
+    \) \
+    -delete
+
+  find "tmp_install/${_gemdir}/extensions/" \
+    -type f \
+    \( \
+      -iname "mkmf.log" -o \
+      -iname "gem_make.out" \
+    \) \
+    -delete
+}
+
+check() {
+  cd $_gemname-$pkgver
+  local _gemdir="$(gem env gemdir)"
+  GEM_HOME="tmp_install/${_gemdir}" rake spec
+}
 
 package() {
-  local _gemdir="$(ruby -e'puts Gem.default_dir')"
-  gem install --ignore-dependencies --no-user-install -i "$pkgdir/$_gemdir" -n "$pkgdir/usr/bin" $_gemname-$pkgver.gem
-  rm "$pkgdir/$_gemdir/cache/$_gemname-$pkgver.gem"
-  install -D -m644 "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/LICENSE.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  cd $_gemname-$pkgver
+
+  cp --archive --verbose tmp_install/* "${pkgdir}"
+
+  install -Dm0644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
+  install -Dm0644 ChangeLog.md "$pkgdir/usr/share/doc/$pkgname/CHANGELOG.md"
 }
+
+# vim: set ts=2 sw=2 et: