1 files changed, 64 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..a430b2c70980
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,64 @@
+# Maintainer: Jonne Haß <me@jhass.eu>
+# Contributor: Sven-Hendrik Haase <sh@lutzhaase.com>
+# Contributor: Sergey Shatunov <me@prok.pw>
+# Contributor: Thomas Dziedzic <gostrc@gmail.com>
+# Contributor: Allan McRae <allan@archlinux.org>
+# Contributor: John Proctor <jproctor@prium.net>
+# Contributor: Jeramy Rutley <jrutley@gmail.com>
+
+_rubyver=2.4
+pkgname=ruby2.4
+pkgver=${_rubyver}.5
+pkgdesc='An object-oriented language for quick and easy programming'
+pkgrel=2
+arch=(x86_64)
+url='http://www.ruby-lang.org/en/'
+license=(BSD custom)
+depends=(gdbm openssl libffi libyaml gmp zlib)
+optdepends=('tk: for Ruby/TK')
+makedepends=(doxygen graphviz ttf-dejavu tk)
+options=(!emptydirs)
+source=(https://cache.ruby-lang.org/pub/ruby/${pkgver:0:3}/ruby-${pkgver}.tar.xz)
+sha512sums=('658f676c623109f4c7499615e191c98c3dd72cfcaeeaf121337d0b8a33c5243145edd50ec5e2775f988e3cd19788984f105fa165e3049779066566f67172c1b4')
+
+build() {
+  cd ruby-${pkgver}
+
+  PKG_CONFIG=/usr/bin/pkg-config ./configure \
+    --prefix=/opt/ruby${_rubyver} \
+    --program-suffix=-${_rubyver} \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --sharedstatedir=/var/lib \
+    --libexecdir=/usr/lib/ruby \
+    --enable-shared \
+    --disable-rpath \
+    --with-dbm-type=gdbm_compat
+
+  make ruby
+}
+
+check() {
+  cd ruby-${pkgver}
+
+  make test
+}
+
+package() {
+  cd ruby-${pkgver}
+
+  make DESTDIR="${pkgdir}" install-nodoc
+
+  install -dm755 $pkgdir/usr/bin
+  install -dm755 $pkgdir/usr/lib
+
+  for i in erb irb rdoc ri ruby testrb rake gem; do
+    ln -s /opt/$pkgname/bin/$i-${_rubyver} $pkgdir/usr/bin/$i-${_rubyver}
+    ln -s /opt/$pkgname/bin/$i-${_rubyver} $pkgdir/opt/$pkgname/bin/$i
+  done
+
+  ln -s /opt/$pkgname/lib/libruby.so.${_rubyver} $pkgdir/usr/lib/libruby.so.${_rubyver}
+
+  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
+  install -D -m644 BSDL "${pkgdir}/usr/share/licenses/$pkgname/BSDL"
+}