1 files changed, 52 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..d3a377332c80
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,52 @@
+# Maintainer: Hans-Nikolai Viessmann <hans at viess dot mn>
+# Contributor: XZS <d dot f dot fischer at web dot de>
+# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
+# Contributor: Rémy Oudompheng <remy@archlinux.org>
+# Contributor: Firmicus <francois . archlinux . org>
+
+pkgname=tllocalmgr-git
+_pkgname='texlive-localmanager'
+pkgver=v0.7.r3.gbbd8488
+pkgrel=1
+pkgdesc='A shell and command-line utility to manage TeXLive on Arch Linux'
+arch=('any')
+url='https://git.archlinux.org/users/remy/texlive-localmanager.git/'
+license=('GPL')
+provides=("texlive-localmanager-git=$pkgver")
+conflicts=('texlive-localmanager'
+           'texlive-localmanager-git')
+depends=('texlive-core>=2011'
+         'perl-libwww'
+         'perl-term-shellui'
+         'perl-term-readline-gnu'
+         'perl-list-moreutils'
+         'perl-lwp-protocol-https')
+makedepends=('git')
+
+source=("${_pkgname}::git://git.archlinux.org/users/remy/texlive-localmanager.git"
+        'tllocalmgr.patch')
+sha256sums=('SKIP'
+            '22222ff329919ee6a16ffd489b0213b14f8169d9daf6ef1a82aa5ab37538c236')
+
+pkgver() {
+  cd $_pkgname
+  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd $_pkgname
+
+  # enhances the tllocalmgr script a bit
+  # thanks: @sharethewisdom and @cobaltspace
+  patch -p1 < "$srcdir/tllocalmgr.patch"
+}
+
+package() {
+  cd $_pkgname
+  install -d $pkgdir/usr/{bin,share/texmf/arch/tlpkg/TeXLive}
+  install -m755 tllocalmgr $pkgdir/usr/bin/
+  cd tlpkg/TeXLive
+  for _f in *; do
+    install -m644 $_f $pkgdir/usr/share/texmf/arch/tlpkg/TeXLive/
+  done
+}