1 files changed, 46 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..34610de6df01
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Luka Perkov <luka.perkov@sartura.hr>
+
+pkgname=ubus-lua-git
+_gitname=ubus
+pkgver=r210.f361bfa
+pkgrel=1
+pkgdesc='An embedded bus system developed for OpenWrt. It is like dbus but simple and small.'
+url='http://nbd.name/gitweb.cgi?p=luci2/ubus.git'
+arch=('i686' 'x86_64' 'armv7h')
+license=('LGPLv2.1')
+depends=('libubox-lua-git' 'json-c' 'lua51')
+makedepends=('git' 'cmake' 'gcc' 'make' 'patch' 'pkg-config')
+conflicts=('ubus' 'ubus-git')
+provides=('ubus')
+source=('git://nbd.name/luci2/ubus.git' '001-lua-version.patch' '002-ubusd-location.patch')
+md5sums=('SKIP' 'SKIP' 'SKIP')
+
+pkgver() {
+	cd "$srcdir/$_gitname"
+
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+	cd "$srcdir/$_gitname"
+
+	patch -p1 -i "$srcdir/001-lua-version.patch"
+	patch -p1 -i "$srcdir/002-ubusd-location.patch"
+}
+
+build() {
+	cd "$srcdir/$_gitname"
+
+	cmake CMakeLists.txt \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-DBUILD_EXAMPLES=OFF \
+		-DBUILD_LUA=ON
+
+	make
+}
+
+package() {
+	cd "$srcdir/$_gitname"
+
+	make DESTDIR="$pkgdir" install
+}