1 files changed, 36 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..f7339bfe4df8
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Fabio 'Lolix' Loli <lolix@disroot.org> -> https://github.com/FabioLolix
+# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Ionut Biru <ibiru@archlinux.org>
+# Contributor: Timm Preetz <timm@preetz.us>
+
+pkgname=vala-0.42
+pkgver=0.42.7
+pkgrel=1
+pkgdesc='Compiler for the GObject type system'
+url='https://wiki.gnome.org/Projects/Vala'
+arch=(x86_64)
+license=(LGPL)
+depends=(glib2 gtk-doc graphviz ttf-font pkg-config gcc)
+makedepends=(libxslt vala git help2man autoconf-archive)
+checkdepends=(dbus libx11 gobject-introspection)
+provides=(vala valadoc libvala-${pkgver%.*}.so libvaladoc-${pkgver%.*}.so)
+conflicts=(vala valadoc)
+source=("https://download.gnome.org/sources/vala/0.42/vala-${pkgver}.tar.xz")
+sha256sums=('03dd5226e373eb1f0a602411f87e5c64213e2791139ce23f0fa8d0dbf4d23309')
+
+build() {
+  cd "vala-$pkgver"
+  ./configure --prefix=/usr
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd "vala-$pkgver"
+  make check
+}
+
+package() {
+  cd "vala-$pkgver"
+  make DESTDIR="$pkgdir" install
+}