1 files changed, 52 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..aa82e22aefbf
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,52 @@
+# Maintainer: zt <nwowens32@gmail.com>
+pkgname=vencord-desktop-git
+pkgdesc="A standalone Electron app that loads Discord & Vencord"
+pkgver=r41.8b68eef
+pkgrel=1
+
+arch=("x86_64" "aarch64")
+url="https://github.com/Vencord/Desktop"
+license=('GPL')
+
+depends=()
+makedepends=("nodejs" "npm")
+optdepends=(
+  'libnotify: Notifications'
+  'xdg-utils: Open links, files, etc'
+)
+
+provides=("vencord")
+conflicts=("vencord")
+
+source=("${pkgname}::git+${url}.git" "vencord.desktop")
+
+sha256sums=('SKIP'
+            'cd4d39fb009bfee33709c26c010a8fe70a76ee3c00006e822da2fec692a165d5')
+
+pkgver() {
+  cd "$pkgname"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "$pkgname"
+
+  npm i pnpm
+  export PATH="$PWD/node_modules/.bin:$PATH"
+  npm run build
+  npm run package:dir
+}
+
+package() {
+  cd "$srcdir"
+
+  install -d "$pkgdir"/opt/vencord
+  cp -R "$pkgname/dist/linux-unpacked/." "$pkgdir/opt/vencord"
+
+  install -Dm 644 "vencord.desktop" "$pkgdir/usr/share/applications/vencord.desktop"
+  install -Dm 644 "$pkgname/static/icon.png" "$pkgdir/usr/share/pixmaps/vencord.png"
+  install -Dm 644 "$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+  install -d "$pkgdir"/usr/bin
+  ln -s /opt/vencord/vencorddesktop "$pkgdir"/usr/bin/vencord
+}