1 files changed, 45 insertions, 18 deletions
diff --git a/PKGBUILD b/PKGBUILD
index 72d07759ccd7..0942ee8f8ade 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,36 +1,63 @@
+# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>
 # Maintainer: László Várady <laszlo.varady93@gmail.com>
 # Contributor: Aleksandar Trifunović <akstrfn at gmail dot com>
 # Contributor: Daichi Shinozaki <dsdseg at gmail dot com>
 
 pkgname=wangle
-pkgver=2023.04.10.00
+pkgver=2024.01.22.00
 pkgrel=1
 pkgdesc="C++ networking library providing client/server abstractions for building services"
 arch=('x86_64')
 url="https://github.com/facebook/wangle"
-license=('Apache')
-depends=('boost' 'boost-libs' 'google-glog' 'fizz' 'folly' 'libevent' 'openssl' 'fmt')
-makedepends=('cmake' 'double-conversion' 'gflags' 'gtest' 'gmock')
-source=("${url}/archive/v${pkgver}.tar.gz")
-sha256sums=('0021bbf234c7ceef99c54981e62250f5419e77fc15a63709ff379b6b2b892b19')
+license=('Apache-2.0')
+depends=(
+  'double-conversion'
+  'fizz'
+  'fmt'
+  'folly'
+  'gcc-libs'
+  'gflags'
+  'glibc'
+  'google-glog'
+  'openssl'
+)
+makedepends=(
+  'boost'
+  'cmake'
+  'gtest'
+)
+provides=(libwangle.so)
+
+source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
+sha256sums=('e29a68f293c0aa3bd9e5c2e0a137d7a0c4e86c26737344f1d1671d0984e3ff09')
 
 build() {
-    cd "$pkgname-$pkgver/$pkgname"
-    cmake -S . -B build \
-          -DCMAKE_C_FLAGS:STRING="${CFLAGS}" \
-          -DCMAKE_CXX_FLAGS:STRING="${CXXFLAGS}" \
-          -DCMAKE_EXE_LINKER_FLAGS:STRING="${LDFLAGS}" \
-          -DCMAKE_INSTALL_PREFIX=/usr \
-          -DCMAKE_BUILD_TYPE=Release
-    cmake --build build
+  cd "$pkgname-$pkgver/$pkgname"
+
+  cmake -S . -B build \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -Wno-dev \
+    -DBUILD_TESTS=ON \
+    -DBUILD_SHARED_LIBS=ON \
+    -DPACKAGE_VERSION="${pkgver}"
+  cmake --build build
 }
 
 check() {
-    cd "$pkgname-$pkgver/$pkgname"
-    #cmake --build build --target test
+  cd "$pkgname-$pkgver/$pkgname"
+
+  ctest --test-dir build --output-on-failure \
+    -E SSLContextManagerTest
 }
 
 package() {
-    cd "$pkgname-$pkgver/$pkgname"
-    cmake --build build --target install -- DESTDIR="$pkgdir/"
+  cd "$pkgname-$pkgver/$pkgname"
+
+  DESTDIR="${pkgdir}" cmake --install build
+
+  # Remove empty directories to avoid namcap warnings
+  rm -r "${pkgdir}/usr/include/wangle/service/test"
+  rm -r "${pkgdir}/usr/include/wangle/ssl/test/certs"
+  rm -r "${pkgdir}/usr/include/wangle/util/test"
 }