summarylogtreecommitdiffstats
path: root/PKGBUILD
diff options
context:
space:
mode:
Diffstat (limited to 'PKGBUILD')
-rw-r--r--PKGBUILD49
1 files changed, 49 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..492dd4368236
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: carstene1ns <url/mail: arch carsten-teibes de>
+# Contributor: Frederic Bezies <fredbezies*gmail>
+# Contributor: Ronan Rabouin <darkbaboon*gmail>
+
+pkgname=yamagi-quake2
+pkgver=5.21
+pkgrel=1
+pkgdesc="Enhanced Quake II engine optimized for modern systems"
+url="http://www.yamagi.org/quake2/"
+arch=('i686' 'x86_64')
+license=('custom: Info-ZIP' 'GPL2')
+depends=('libjpeg' 'sdl2' 'libxxf86vm' 'libvorbis')
+optdepends=('quake2-demo: shareware data files'
+ 'openal: alternative audio backend')
+makedepends=('openal' 'mesa')
+install=$pkgname.install
+changelog=$pkgname.ChangeLog
+source=("http://deponie.yamagi.org/quake2/quake2-$pkgver.tar.xz"
+ "$pkgname.desktop")
+sha256sums=('ffa9f0c3471aa04c5b11678b54505dfdfad0d7bca845a0a1fa4790259eb69be4'
+ '984cba7e43033b5b2339879474854006b0340c55b6c20693df88e983e0f2daf2')
+
+build() {
+ cd quake2-$pkgver
+
+ make WITH_SYSTEMWIDE=yes WITH_SYSTEMDIR=/usr/share/$pkgname
+}
+
+package() {
+ cd quake2-$pkgver
+
+ # client + server binaries
+ install -Dm755 release/quake2 "$pkgdir"/usr/bin/$pkgname
+ install -m755 release/q2ded "$pkgdir"/usr/bin/yamagi-q2ded
+
+ # game library
+ install -Dm644 release/baseq2/game.so "$pkgdir"/usr/share/$pkgname/baseq2/game.so
+
+ # doc
+ install -Dm644 README "$pkgdir"/usr/share/doc/$pkgname/README
+ install -m644 stuff/yq2.cfg "$pkgdir"/usr/share/doc/$pkgname
+
+ # desktop entry
+ install -Dm644 ../$pkgname.desktop "$pkgdir"/usr/share/applications/$pkgname.desktop
+ install -Dm644 stuff/icon/Quake2.png "$pkgdir"/usr/share/pixmaps/$pkgname.png
+
+ # licenses
+ install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}