1 files changed, 46 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..68ef065dfa40
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgname=zzuf-git
+pkgver=0.14.669.d16576b
+pkgrel=1
+pkgdesc="Transparent application input fuzzer"
+url='https://github.com/samhocevar/zzuf'
+arch=('i686' 'x86_64')
+license=('custom:WTF')
+depends=('glibc')
+makedepends=('git')
+provides=('zzuf')
+conflicts=('zzuf')
+source=(${pkgname}::git+https://github.com/samhocevar/zzuf)
+sha512sums=('SKIP')
+
+pkgver() {
+  cd ${pkgname}
+  printf "%s.%s.%s" "$(git describe --tags --abbrev=0|cut -dv -f2)" \
+    "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd ${pkgname}
+  autoreconf -fiv
+}
+
+build() {
+  cd ${pkgname}
+  ./configure --prefix=/usr
+  make
+}
+
+check() {
+  cd ${pkgname}
+  # ignore test results because of upstream bug #7
+  make check||true
+}
+
+package() {
+  cd ${pkgname}
+  make DESTDIR="${pkgdir}" install
+  install -Dm 644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+# vim: ts=2 sw=2 et: