# Maintainer: Josef Miegl <josef@miegl.cz>
# Contributor: Gaetan Bisson <bisson@archlinux.org
# Contributor: Brad Fanella <bradfanella@archlinux.us>
# Contributor: Daenyth <Daenyth+Arch [at] gmail [dot] com>
# Contributor: Corrado Primier <bardo@aur.archlinux.org>
# Contributor: ice-man <icemanf@gmail.com>
# Contributor: codyps <archlinux@codyps.com>

pkgname=aircrack-ng-git
pkgver=20190211.8562674a
pkgrel=1
pkgdesc="WiFi security auditing tools suite"
url="https://aircrack-ng.org"
arch=('i686' 'x86_64' 'aarch64' 'armv7h')
license=('GPL2')
makedepends=('git' 'python')
depends=('gcc-libs' 'libnl' 'openssl' 'sqlite' 'hwloc' 'pcre' 'libpcap')
optdepends=('python: dump-join, airgraph-ng, versuck-ng, airdrop-ng')
provides=("${pkgname%-git}" 'aircrack-ng-scripts')
conflicts=("${pkgname%-git}" 'aircrack-ng-scripts')
replaces=('aircrack-ng-svn' 'aircrack-ng-scripts')
source=("git+https://github.com/aircrack-ng/aircrack-ng.git")
sha256sums=('SKIP')

pkgver() {
  cd "${pkgname%-git}"
  git log -1 --format='%cd.%h' --date=short | tr -d -
}

build() {
  cd "${pkgname%-git}"
  autoreconf -f -i
  ./configure --with-experimental --with-ext-scripts --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  make
}

package() {
  cd "${pkgname%-git}"
  make DESTDIR="${pkgdir}" install
}

# vim:set ts=2 sw=2 et: