# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
# Contributor: Bruno Pagani <archange@archlinux.org>

_android_arch=armv7a-eabi

pkgname=android-${_android_arch}-libavif
pkgver=1.0.4
pkgrel=1
arch=('any')
pkgdesc="Library for encoding and decoding .avif files (Android ${_android_arch})"
url="https://github.com/AOMediaCodec/libavif"
license=('LicenseRef-libavif')
depends=("android-${_android_arch}-aom"
         "android-${_android_arch}-dav1d"
         "android-${_android_arch}-svt-av1"
         "android-${_android_arch}-libpng"
         "android-${_android_arch}-libjpeg"
         "android-${_android_arch}-libyuv")
makedepends=('android-cmake'
             "android-${_android_arch}-gdk-pixbuf2"
             'nasm')
options=(!strip !buildflags staticlibs !emptydirs)
source=("${url}/archive/v${pkgver}/libavif-${pkgver}.tar.gz")
md5sums=('8c786fd21f8757ace8cc011401e4d420')

build() {
    cd "${srcdir}/libavif-$pkgver"
    source android-env ${_android_arch}

    android-${_android_arch}-cmake \
        -S . \
        -B build \
        -DAVIF_BUILD_APPS=OFF \
        -DAVIF_CODEC_AOM=ON \
        -DAVIF_CODEC_DAV1D=ON \
        -DAVIF_CODEC_RAV1E=ON \
        -DAVIF_CODEC_SVT=ON \
        -DAVIF_BUILD_GDK_PIXBUF=ON \
        -DAVIF_ENABLE_GTEST=OFF \
        -DDAV1D_INCLUDE_DIR="${ANDROID_PREFIX_INCLUDE}" \
        -DDAV1D_LIBRARY="${ANDROID_PREFIX_LIB}/libdav1d.so" \
        -DRAV1E_INCLUDE_DIR="${ANDROID_PREFIX_INCLUDE}/rav1e" \
        -DRAV1E_LIBRARY="${ANDROID_PREFIX_LIB}/librav1e.so" \
        -DSVT_INCLUDE_DIR="${ANDROID_PREFIX_INCLUDE}" \
        -DSVT_LIBRARY="${ANDROID_PREFIX_LIB}/libSvtAv1Enc.so" \
        -DAOM_INCLUDE_DIR="${ANDROID_PREFIX_INCLUDE}" \
        -DAOM_LIBRARY="${ANDROID_PREFIX_LIB}/libaom.so" \
        -DPNG_PNG_INCLUDE_DIR="${ANDROID_PREFIX_INCLUDE}" \
        -DPNG_LIBRARY="${ANDROID_PREFIX_LIB}/libpng.so" \
        -DJPEG_INCLUDE_DIR="${ANDROID_PREFIX_INCLUDE}" \
        -DJPEG_LIBRARY="${ANDROID_PREFIX_LIB}/libjpeg.so"
    sed -i "s|  -lgdk_pixbuf-2.0|  -L${ANDROID_PREFIX_LIB} -lgdk_pixbuf-2.0|g" build/contrib/gdk-pixbuf/CMakeFiles/pixbufloader-avif.dir/link.txt
    make -C build $MAKEFLAGS
}

package() {
    cd "${srcdir}/libavif-$pkgver"
    source android-env ${_android_arch}

    make -C build DESTDIR="$pkgdir" install
    find "${pkgdir}/${ANDROID_PREFIX_LIB}" -type f -name "*.so" -exec ${ANDROID_STRIP} -g --strip-unneeded {} \;
}