# sMaintainer: Bernhard Landauer <bernhard@manjaro.org>
# Maintainer: James Kittsmiller (AJSlye) <james@nulogicsystems.com>

_pkgname=AppImageLauncher
pkgname=appimagelauncher
pkgver=1.2.2
pkgrel=2
pkgdesc="A Helper application for running and integrating AppImages."
arch=('x86_64')
url="https://github.com/TheAssassin/AppImageLauncher"
license=('MIT')
depends=('binutils'
    'boost'
    'cairo'
    'desktop-file-utils'
    'fuse'
    'gtest'
    'libarchive'
    'libbsd'
    'qt5-base'
    'shared-mime-info')
makedepends=('git' 'cmake' 'wget' 'vim' 'qt5-tools')
conflicts=('appimagelauncher-git')
source=("git+$url.git#tag=v$pkgver"
    'appimage-binfmt-remove.hook')
sha256sums=('SKIP'
            '72a2630cf79b8f90bc21eae1d9f40c07fe77ce22df46c511b500f514455d7c81')

prepare() {
  cd $_pkgname
  git submodule update --init --recursive
}

build() {
  cd $_pkgname
  cmake . -DCMAKE_INSTALL_PREFIX:PATH=/usr/ -DUSE_SYSTEM_GTEST=ON -DUSE_SYSTEM_XZ=ON \
          -DUSE_SYSTEM_LIBARCHIVE=ON
  make
}

package() {
  install -Dm644 -t $pkgdir/usr/share/libalpm/hooks *.hook

  cd $_pkgname
  make DESTDIR="$pkgdir" install
  install -Dm644 LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/LICENSE

  # fix lib location
  mv $pkgdir/usr/lib64/* $pkgdir/usr/lib/
  rm -rf $pkgdir/usr/lib64
}